Files
OrangePi_CM5/arch/arm64/kernel/vmlinux.lds.S
T

188 lines
4.1 KiB
ArmAsm
Raw Normal View History

2012-04-20 14:45:54 +01:00
/*
* ld script to make ARM Linux kernel
* taken from the i386 version by Russell King
* Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
*/
#include <asm-generic/vmlinux.lds.h>
#include <asm/thread_info.h>
#include <asm/memory.h>
#include <asm/page.h>
2015-01-21 17:36:06 -08:00
#include <asm/pgtable.h>
2012-04-20 14:45:54 +01:00
2014-06-24 16:51:36 +01:00
#include "image.h"
/* .exit.text needed in case of alternative patching */
#define ARM_EXIT_KEEP(x) x
#define ARM_EXIT_DISCARD(x)
2012-04-20 14:45:54 +01:00
OUTPUT_ARCH(aarch64)
2014-05-16 18:26:01 +01:00
ENTRY(_text)
2012-04-20 14:45:54 +01:00
jiffies = jiffies_64;
2012-12-07 18:40:43 +00:00
#define HYPERVISOR_TEXT \
/* \
2015-03-19 16:42:26 +00:00
* Align to 4 KB so that \
* a) the HYP vector table is at its minimum \
* alignment of 2048 bytes \
* b) the HYP init code will not cross a page \
* boundary if its size does not exceed \
* 4 KB (see related ASSERT() below) \
2012-12-07 18:40:43 +00:00
*/ \
2015-03-19 16:42:26 +00:00
. = ALIGN(SZ_4K); \
2012-12-07 18:40:43 +00:00
VMLINUX_SYMBOL(__hyp_idmap_text_start) = .; \
*(.hyp.idmap.text) \
VMLINUX_SYMBOL(__hyp_idmap_text_end) = .; \
VMLINUX_SYMBOL(__hyp_text_start) = .; \
*(.hyp.text) \
VMLINUX_SYMBOL(__hyp_text_end) = .;
2015-06-01 13:40:33 +02:00
#define IDMAP_TEXT \
. = ALIGN(SZ_4K); \
VMLINUX_SYMBOL(__idmap_text_start) = .; \
*(.idmap.text) \
VMLINUX_SYMBOL(__idmap_text_end) = .;
/*
* The size of the PE/COFF section that covers the kernel image, which
* runs from stext to _edata, must be a round multiple of the PE/COFF
* FileAlignment, which we set to its minimum value of 0x200. 'stext'
* itself is 4 KB aligned, so padding out _edata to a 0x200 aligned
* boundary should be sufficient.
*/
PECOFF_FILE_ALIGNMENT = 0x200;
#ifdef CONFIG_EFI
#define PECOFF_EDATA_PADDING \
.pecoff_edata_padding : { BYTE(0); . = ALIGN(PECOFF_FILE_ALIGNMENT); }
#else
#define PECOFF_EDATA_PADDING
#endif
2015-01-21 17:36:06 -08:00
#ifdef CONFIG_DEBUG_ALIGN_RODATA
#define ALIGN_DEBUG_RO . = ALIGN(1<<SECTION_SHIFT);
#define ALIGN_DEBUG_RO_MIN(min) ALIGN_DEBUG_RO
#else
#define ALIGN_DEBUG_RO
#define ALIGN_DEBUG_RO_MIN(min) . = ALIGN(min);
#endif
2012-04-20 14:45:54 +01:00
SECTIONS
{
/*
* XXX: The linker does not define how output sections are
* assigned to input sections when there are multiple statements
* matching the same input section name. There is no documented
* order of matching.
*/
/DISCARD/ : {
ARM_EXIT_DISCARD(EXIT_TEXT)
ARM_EXIT_DISCARD(EXIT_DATA)
EXIT_CALL
*(.discard)
*(.discard.*)
}
. = PAGE_OFFSET + TEXT_OFFSET;
.head.text : {
_text = .;
HEAD_TEXT
}
2015-01-21 17:36:06 -08:00
ALIGN_DEBUG_RO
2012-04-20 14:45:54 +01:00
.text : { /* Real text segment */
_stext = .; /* Text and read-only data */
__exception_text_start = .;
*(.exception.text)
__exception_text_end = .;
IRQENTRY_TEXT
TEXT_TEXT
SCHED_TEXT
LOCK_TEXT
2012-12-07 18:40:43 +00:00
HYPERVISOR_TEXT
2015-06-01 13:40:33 +02:00
IDMAP_TEXT
2012-04-20 14:45:54 +01:00
*(.fixup)
*(.gnu.warning)
. = ALIGN(16);
*(.got) /* Global offset table */
}
2015-01-21 17:36:06 -08:00
ALIGN_DEBUG_RO
2012-04-20 14:45:54 +01:00
RO_DATA(PAGE_SIZE)
EXCEPTION_TABLE(8)
2013-08-23 16:16:42 +01:00
NOTES
2015-01-21 17:36:06 -08:00
ALIGN_DEBUG_RO
2012-04-20 14:45:54 +01:00
_etext = .; /* End of text and rodata section */
2015-01-21 17:36:06 -08:00
ALIGN_DEBUG_RO_MIN(PAGE_SIZE)
2012-04-20 14:45:54 +01:00
__init_begin = .;
INIT_TEXT_SECTION(8)
.exit.text : {
ARM_EXIT_KEEP(EXIT_TEXT)
}
2015-01-21 17:36:06 -08:00
ALIGN_DEBUG_RO_MIN(16)
2012-04-20 14:45:54 +01:00
.init.data : {
INIT_DATA
INIT_SETUP(16)
INIT_CALLS
CON_INITCALL
SECURITY_INITCALL
INIT_RAM_FS
}
.exit.data : {
ARM_EXIT_KEEP(EXIT_DATA)
}
PERCPU_SECTION(64)
. = ALIGN(PAGE_SIZE);
2012-04-20 14:45:54 +01:00
__init_end = .;
2014-11-14 15:54:08 +00:00
. = ALIGN(4);
.altinstructions : {
__alt_instructions = .;
*(.altinstructions)
__alt_instructions_end = .;
}
.altinstr_replacement : {
*(.altinstr_replacement)
}
. = ALIGN(PAGE_SIZE);
_data = .;
_sdata = .;
RW_DATA_SECTION(64, PAGE_SIZE, THREAD_SIZE)
PECOFF_EDATA_PADDING
_edata = .;
2012-04-20 14:45:54 +01:00
BSS_SECTION(0, 0, 0)
. = ALIGN(PAGE_SIZE);
idmap_pg_dir = .;
. += IDMAP_DIR_SIZE;
swapper_pg_dir = .;
. += SWAPPER_DIR_SIZE;
2012-04-20 14:45:54 +01:00
_end = .;
STABS_DEBUG
2014-06-24 16:51:36 +01:00
HEAD_SYMBOLS
2012-04-20 14:45:54 +01:00
}
2012-12-07 18:40:43 +00:00
/*
2015-06-01 13:40:33 +02:00
* The HYP init code and ID map text can't be longer than a page each,
2015-03-19 16:42:26 +00:00
* and should not cross a page boundary.
2012-12-07 18:40:43 +00:00
*/
2015-03-19 16:42:26 +00:00
ASSERT(__hyp_idmap_text_end - (__hyp_idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
"HYP init code too big or misaligned")
2015-06-01 13:40:33 +02:00
ASSERT(__idmap_text_end - (__idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
"ID map text too big or misaligned")
2014-06-24 16:51:37 +01:00
/*
* If padding is applied before .head.text, virt<->phys conversions will fail.
*/
ASSERT(_text == (PAGE_OFFSET + TEXT_OFFSET), "HEAD is misaligned")